Chapter IV: Appendix: A

Adjuncts to Algol 60

List Entities

The delimiter list is a declarator and a specifier.

<list identifier> ::= <identifier>

<loop expression> ::= <for clause> <arithmetic expression>
| <for clause> <loop expression>
| <for clause> (<list>)

<list element> ::= <arithmetic expression>
| <loop expression>
| <list identifier>

<list> ::= <list element>
| <list>, <list element>

<list declaration> ::= list <list identifier> := <list>

Format Entities

The delimiter format is a declarator and a specifier.

<format identifier> ::= <identifier>

<simple format expression> ::='(<Fortran format>[2])'
| <format identifier>

<format expression> ::= <simple format expression>
| <if clause> <simple format expression>
else <format expression>

<format declaration> ::= format <format identifier> := <format
expression>

String Expression

<string expression> ::= <string>
| <if clause> <string>
else <string expression>

External Declaration

The delimiter external is a declarator.

<external identifier> ::= <identifier>

<external list> ::= <external identifier>
| <external identifier>, <external list>

<external declaration> ::= external <external list>
| <type> external <external list>